/give - アイテムを渡す

プレイヤーにアイテム、またはブロックを与える (give)コマンドです。 個数やデータ値を細かく指定できる他、アイテムの場合はコマンド専用の特殊な効果を付けることができます。

アイテムを1つ渡す

/give <誰に> <アイテム名>

渡す相手とアイテム名（またはブロック名）を、この順番に書きます。 順番を間違えたり、間にスペースが無いとエラーになります。

# 自分にリンゴを渡す
/give @s apple
# プレイヤー全員にTNTブロックを渡す
/give @a tnt

アイテム名はアイテム一覧またはブロック一覧から選んでください。日本語名は使えません。

# 自分にコマンドブロックを渡す
/give @s command_block

アイテムの個数を指定する

/give <誰に> <アイテム名> [個数]

個数を指定する場合はアイテム名に続けて数字を入力します。 何も入力しないと、上の例のように1つになります。

1スタックの数や、インベントリの上限を超えて指定できます。

# 自分にダイヤモンドを10個渡す
/give @s diamond 10
# 1スタックに収まらなくても良い。64個・36個で手に入る。
/give @s diamond 100
# インベントリに入り切らなかった場合、残りは手に入らないだけでエラーにはならない。
/give @s diamond 10000

アイテムのデータ値を指定する

/give <誰に> <アイテム名> [個数] [データ値]

いくつかのアイテムはデータ値を持っていて、同じアイテムで異なる状態を表現します。 例えば羊毛 (wool)や染色ガラス (stained_glass)などはデータ値で色が異なります。どの色がどの番号か試してみましょう。

# データ値は0から数えます。0は指定無しの「普通」の状態です
/give @s wool 1 0
# 上と同じ
/give @s wool 1
# 1から変化があります(そのデータ値を持っていないアイテムは0に置き換えられる)
/give @s wool 1 1
# 最大で15までありえます（アイテムによっては途中までしかありません）
/give @s wool 1 15

アイテムに特別な設定を加える

/give <誰に> <アイテム名> [個数] [データ値] [設定]

この設定部分はJSON形式と呼ばれる記述の仕方をします。 この設定は/replaceitemでも使えます。

壊せるブロックを指定する

minecraft:can_destroy

アドベンチャーモードで指定したブロックを壊せる (can_destory)ようになります。 サバイバル・クリエイティブでは設定に関係なく壊すことができます。

# 「石・丸石」だけ壊せる「鉄のツルハシ」を与える
/give @s iron_pickaxe 1 0 {"minecraft:can_destroy":{"blocks":["stone","cobblestone"]}}

これは次のような形式が1行になっています。

{
  "minecraft:can_destroy": {
    "blocks": ["stone", "cobblestone"]
  }
}

置けるブロックを指定する

minecraft:can_place_on

アドベンチャーモードで指定したブロックへ置ける (can_place_on)ようになります。 サバイバル・クリエイティブでは設定に関係なく置くことができます。

# 「金ブロック」にだけ置ける「金の感圧版」を与える
/give @s pressure_plate 1 0 {"minecraft:can_place_on":{"blocks":["gold_block"]}}

{
  "minecraft:can_place_on": {
    "blocks": ["gold_block"]
  }
}

死んでも失わない

minecraft:keep_on_death

このアイテムは死んだとき (on_death)に、そのアイテムを失わずに持ち続け (keep)ます。

# 「鉄のツルハシ」を失わないようにする（例えばゲームの初期装備として）
/give @s iron_pickaxe 1 0 {"minecraft:keep_on_death":{}}

中の設定は必要ありませんが、空のオブジェクト{}を入れることになっています。

{
  "minecraft:keep_on_death": {}
}

全員のすべてのアイテムを死んでも残したい場合はゲームルールの方を変更します。

捨てられなくする

minecraft:item_lock

与えたアイテム (item)を固定 (lock)して捨てられなくします。 固定の仕方は2種類あります。

ただしブロックを置いたり、食べ物を食べることで無くなることはあります。 アイテムが使えなくなったり、消費しなくなったりするわけではありません。

インベントリ内は移動可

{"mode":"lock_in_inventory"}

インベントリ内 (in_inventory)に固定 (lock)します。 この場合はインベントリ内であれば自由に移動させることができます。

/give @s iron_pickaxe 1 0 {"minecraft:item_lock":{"mode":"lock_in_inventory"}}

{
  "minecraft:item_lock": {
    "mode": "lock_in_inventory"
  }
}

指定したスロットに固定

{"mode":"lock_in_slot"}

受け取った時のスロットに (in_slot)固定 (lock)します。 この場合はスロット間の移動ができず、いっさい動かすことができません。

/give @s iron_pickaxe 1 0 {"minecraft:item_lock":{"mode":"lock_in_slot"}}

{
  "minecraft:item_lock": {
    "mode": "lock_in_slot"
  }
}

場所を指定したい場合は/replaceitemを使います。/giveの場合は空いているスロットへ順番に入ります。

複数組み合わせる

それぞれの要素は同時に使うことができます。 その場合にはコンマを付けて繋げます。

{
  "minecraft:can_destroy": {
    "blocks": ["stone", "cobblestone"]
  },  <- コンマを付けてつなげる
  "minecraft:keep_on_death": {},  <- コンマを付けてつなげる
  "minecraft:item_lock": {
    "mode": "lock_in_inventory"
  }  <- 最後はコンマ無し
}