/teleport(/tp) - エンティティを移動させる
/teleport
はエンティティを瞬間移動 させるコマンドです。また、移動後の状態も併せて指定できます。
指定先へ移動する
/teleport <誰を> <どこへ>
「どこへ」の入力の仕方は「座標」と「エンティティ」の2通りがあります。
座標を決めて移動する
座標を指定するのが一般的です。
相対座標・ローカル座標の場合は、自分を基準にして座標を決定します。
# 自分を座標(0, 200, 0)に移動
/tp @s 0 200 0
# 自分を自分からみて座標(~5, ~5, ~5)に移動
/tp @s ~5 ~5 ~5
# 自分を10ブロック前の位置に移動
/tp @s ^ ^ ^10
エンティティを決めて移動する
移動先には座標の他にもエンティティを対象にできます。 ただし、移動先のエンティティは1体にしなくてはいけません。
# 自分をSteveのいる場所に移動
/tp @s Steve
# ランダムなプレイヤー1人をもっとも近いクリーパーの元へ移動
/tp @r @e[type=creeper, c=1]
# 移動先が複数なのでエラー
/tp @s @e
自分を移動する場合は@sを省略できる
自分@s
を移動させる場合は移動元の対象を省略できます。
/teleport <どこへ>
# 対象が自分自身(@s)なら省略可能。
/tp ~5 ~5 ~5
# これと同じ
/tp @s ~5 ~5 ~5
# 自分をクリーパーのいる場所に移動。クリーパーを移動させるわけではない。
/tp @e[type=creeper, c=1]
# これと同じ
/tp @s @e[type=creeper, c=1]
移動先にブロックがあるかを確認して移動
/teleport (<誰を>) <どこへ> [ブロック確認するか]
ブロックの確認をすると、移動先にブロックがあれば対象を移動しません。
# 10ブロック下に移動。ただしそこにブロックがあれば移動しない。
/tp @s ~ ~-10 ~ true
# 初期値はfalseなので確認しない場合は入力する必要はない(してもしなくても同じ)
/tp @s ~ ~-10 ~ false
# これと同じ
/tp @s ~ ~-10 ~
体の向きを指定する
/teleport (<誰を>) <どこへ> [体の向き] [顔の向き] [ブロック確認するか]
[体の向き]
はy軸を基準にした回転。どの水平方向(東西南北)を向いているか。[顔の向き]
はx軸を基準にした回転。どの垂直方向(上下)を向いているか。
詳しくはターゲットセレクタのry
,rx
の項目を参照。
# 自分を、真南・真正面を向いて移動
/tp @s ~ ~ ~ 0 0
# 自分を、真西・真上を向いて移動
/tp @s ~ ~ ~ -90 90
顔の向きを指定して移動
どの地点・対象を見るかで2通りの指定方法があります。
どの地点を見るか
座標を指定して、そこを見るように移動対象の顔の向きを変えます。
/teleport (<誰を>) <どこへ> facing <顔を向ける位置> [ブロック確認するか]
# 移動して世界の中心を見る
/tp @s ~ ~ ~ facing 0 64 0
誰を見るか
エンティティを指定して、そこを見るように移動対象の顔の向きを変えます。
見る目標エンティティは1体になるように絞り込む必要があります。
/teleport (<誰を>) <どこへ> facing <顔を向ける対象> [ブロック確認するか]
# 移動して最も近くのクリーパーを見る
/tp @s ~ ~ ~ facing @e[type=creeper, c=1]